Classes | UGens > Generators > Chaotic

GbmanN : ChaosGen : UGen : AbstractFunction : Object

Gingerbreadman map chaotic generator
Source: Chaos.sc
Subclasses: GbmanL

Description

A non-interpolating sound generator based on the difference equations:

        x(n+1) = 1 - y(n) + |x(n)|
        y(n+1) = x(n)

The behavior of the system is only dependent on its initial conditions.

sclang code translation:

(
var xi = 1.2, yi = 2.1, size = 64;
plot(size.collect { var x; xi = 1 - yi + abs(x = xi); yi = x; xi });
)

Reference: Devaney, R. L. "The Gingerbreadman." Algorithm 3, 15-16, Jan. 1992.

Class Methods

GbmanN.ar(freq: 22050, xi: 1.2, yi: 2.1, mul: 1, add: 0)

Arguments:

freq

Iteration frequency in Hertz

xi

Initial value of x

yi

Initial value of y

mul
add

Inherited class methods

Undocumented class methods

GbmanN.equation

Instance Methods

Inherited instance methods

Examples

// default initial params
{ GbmanN.ar(MouseX.kr(20, SampleRate.ir)) * 0.1 }.play(s);

// change initial params
{ GbmanN.ar(MouseX.kr(20, SampleRate.ir), -0.7, -2.7) * 0.1 }.play(s);

// wait for it...
{ GbmanN.ar(MouseX.kr(20, SampleRate.ir), 1.2, 2.0002) * 0.1 }.play(s);

// as a frequency control
{ SinOsc.ar(GbmanN.ar(40)*400+500)*0.4 }.play(s);