MIDIIn | SuperCollider 3.12.2 Help

Description

This document explains technical details of the MIDI hardware interface class, MIDIIn.

MIDIIn is a simple and direct interface. When MIDI events come into SuperCollider, MIDIIn evaluates simple handler functions.

NOTE: For general programming, users should not use the MIDIIn class directly. See the MIDIFunc and MIDIdef classes for higher level event matching and more flexible handling of event handlers.

Certain MIDI messages are supported only through MIDIIn. These are: sysex, sysrt, smpte.

See the Using MIDI helpfile for practical considerations and techniques for using MIDI in SC.

MIDIIn links MIDI input received from the operating system to a set of user defined functions. Only one set of MIDI input handling functions can be active at a time, they are stored in the following class variables:

noteOff, noteOn, polytouch, control, program, touch, bend, sysex, sysrt, smpte

The first argument these functions receive is an unique identifier that specifies the source of the data.

Class Methods

MIDIIn.findPort(deviceName, portName)

searches for a connected MIDIEndPoint by name.//list connected ins: MIDIClient.init; MIDIClient.sources;

MIDIIn.addFuncTo(what, func)

Add a Function or similar object to be evaluated whenever a particular MIDI message is received. This method is preferable to the setters below, since it will not overwrite any existing functions.

Arguments:

what	A Symbol indicating the message type to wait for, one of `'noteOn'` `'noteOff'`, `'polytouch'`, `'control'`, `'program'`, `'touch'`, `'bend'`, `'sysex'`, `'sysrt'`, `'smpte'`, or `'invalid'` (for invalid sysex messages).
func	A Function or similar object to be evaluated when a message of the specified type is received. See the setters below for the arguments which will be passed at evaluation time.

MIDIIn.removeFuncFrom(what, func)

Remove a Function or similar object from the list of those to be evaluated whenever a particular MIDI message is received. This method is preferable to the setters below, since it will leave any existing functions in place.

Arguments:

what	A Symbol indicating the message type, one of `'noteOn'` `'noteOff'`, `'polytouch'`, `'control'`, `'program'`, `'touch'`, `'bend'`, `'sysex'`, `'sysrt'`, `'smpte'`, or `'invalid'` (for invalid sysex messages).
func	The Function or similar object to be removed.

MIDIIn.replaceFuncTo(what, func, newFunc)

Replace a Function or similar object in the list to be evaluated whenever a particular MIDI message is received with another one. This method is preferable to the setters below, since it will not overwrite any existing functions.

Arguments:

what	A Symbol indicating the message type to wait for, one of `'noteOn'` `'noteOff'`, `'polytouch'`, `'control'`, `'program'`, `'touch'`, `'bend'`, `'sysex'`, `'sysrt'`, `'smpte'`, or `'invalid'` (for invalid sysex messages).
func	The Function or similar object to be replaced.
newFunc	A Function or similar object to be evaluated when a message of the specified type is received. See the setters below for the arguments which will be passed at evaluation time.

MIDIIn.noteOnZeroAsNoteOff

MIDIIn.noteOnZeroAsNoteOff = value

By default this flag is true and SuperCollider interprets incoming MIDI noteOn message with velocity 0 as noteOff messages. In case you do not want this automatic translation, you can set this flag to false

MIDIIn.connectAll(verbose: true)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Platform/linux/SystemOverwrites/extMIDIOut.sc

Connect to all possible MIDI inputs.

Arguments:

verbose

If set to true (default) it will print out the ports found in MIDIClient.init.

MIDIIn.disconnectAll

Disconnect from all MIDI inputs.

Getter/Setters for Specific Message Types

a Function evaluated whenever a MIDI pitch wheel change message is received. It is passed the following arguments:

uid: unique identifier of the MIDI port
MIDIchannel: ranges from 0 to 15
bend: 0 - 16383 (14bits, the midpoint is 8192)

MIDIIn.sysex

MIDIIn.sysex = value

NOTE: The current implementation assembles a complete system exclusive packet before evaluating the function.

Arguments:

(value)

a Function evaluated whenever a MIDI System Exclusive message is received. It is passed the following arguments:

uid: unique identifier of the MIDI port
data: an Int8Array (includes f0 and f7). See manufacturer references for details.

MIDIIn.sysrt

MIDIIn.sysrt = value

index	data	message
2	14bits	song pointer
3	7bits	song select
8		midiclock
10		start
11		continue
12		stop

Arguments:

(value)

a Function evaluated whenever a MIDI System Real-Time message is received. It is passed the following arguments:

uid: unique identifier of the MIDI port
index: ranges from 0 to 15
data

MIDIIn.smpte

MIDIIn.smpte = value

Over MIDI, SMPTE is transmitted at 1/4 frame intervals four times faster than the frame rate.

index	data
0	frames low nibble
1	frames hi nibble
2	seconds low nibble
3	seconds hi nibble
4	minutes low nibble
5	minutes hi nibble
6	hours low nibble
7	hours hi bit OR'ed with frameRate 0 -> 24 fps 2 -> 25 fps 4 -> 30 fps drop frame 6 -> 30 fps

Nibbles are sent in ascending order.

Arguments:

(value)

a Function evaluated whenever a MIDI smpte message is received. It is passed the following arguments:

uid: unique identifier of the MIDI port
index: ranges from 0 to 7
data: 0 - 15 (4bits)

Inherited class methods

Undocumented class methods

MIDIIn.action

MIDIIn.action = value

MIDIIn.bendList

MIDIIn.bendList = value

MIDIIn.connect(inport: 0, device: 0)

MIDIIn.controlList

MIDIIn.controlList = value

MIDIIn.disconnect(inport: 0, device: 0)

MIDIIn.doAction(src, status, a, b, c)

MIDIIn.doBendAction(src, chan, val)

MIDIIn.doControlAction(src, chan, num, val)

MIDIIn.doInvalidSysexAction(src, packet)

MIDIIn.doNoteOffAction(src, chan, num, veloc)

MIDIIn.doNoteOnAction(src, chan, num, veloc)

MIDIIn.doPolyTouchAction(src, chan, num, val)

MIDIIn.doProgramAction(src, chan, val)

MIDIIn.doSMPTEaction(src, frameRate, timecode)

MIDIIn.doSysexAction(src, packet)

MIDIIn.doSysrtAction(src, index, val)

MIDIIn.doTouchAction(src, chan, val)

MIDIIn.invalid

MIDIIn.invalid = value

MIDIIn.noteOffList

MIDIIn.noteOffList = value

MIDIIn.noteOnList

MIDIIn.noteOnList = value

MIDIIn.polyList

MIDIIn.polyList = value

MIDIIn.programList

MIDIIn.programList = value

MIDIIn.touchList

MIDIIn.touchList = value

MIDIIn.waitBend(port, chan, val)

MIDIIn.waitControl(port, chan, num, val)

MIDIIn.waitNoteOff(port, chan, note, veloc)

MIDIIn.waitNoteOn(port, chan, note, veloc)

MIDIIn.waitPoly(port, chan, note, veloc)

MIDIIn.waitProgram(port, chan, num)

MIDIIn.waitTouch(port, chan, val)

Instance Methods

Inherited instance methods

Examples

Quick start for 1 port

(
MIDIIn.connect;    // init for one port midi interface
// register functions:
~noteOff = { arg src, chan, num, vel;    [chan,num,vel / 127].postln; };
~noteOn = { arg src, chan, num, vel;    [chan,num,vel / 127].postln; };
~polytouch = { arg src, chan, num, vel;    [chan,num,vel / 127].postln; };
~control = { arg src, chan, num, val;    [chan,num,val].postln; };
~program = { arg src, chan, prog;        [chan,prog].postln; };
~touch = { arg src, chan, pressure;    [chan,pressure].postln; };
~bend = { arg src, chan, bend;        [chan,bend - 8192].postln; };
~sysex = { arg src, sysex;        sysex.postln; };
~sysrt = { arg src, chan, val;        [chan,val].postln; };
~smpte = { arg src, chan, val;        [chan,val].postln; };
MIDIIn.addFuncTo(\noteOn, ~noteOn);
MIDIIn.addFuncTo(\noteOff, ~noteOff);
MIDIIn.addFuncTo(\polytouch, ~polytouch);
MIDIIn.addFuncTo(\control, ~control);
MIDIIn.addFuncTo(\program, ~program);
MIDIIn.addFuncTo(\touch, ~touch);
MIDIIn.addFuncTo(\bend, ~bend);
MIDIIn.addFuncTo(\sysex, ~sysex);
MIDIIn.addFuncTo(\sysrt, ~sysrt);
MIDIIn.addFuncTo(\smpte, ~smpte);
)

//cleanup
(
MIDIIn.removeFuncFrom(\noteOn, ~noteOn);
MIDIIn.removeFuncFrom(\noteOff, ~noteOff);
MIDIIn.removeFuncFrom(\polytouch, ~polytouch);
MIDIIn.removeFuncFrom(\control, ~control);
MIDIIn.removeFuncFrom(\program, ~program);
MIDIIn.removeFuncFrom(\touch, ~touch);
MIDIIn.removeFuncFrom(\bend, ~bend);
MIDIIn.removeFuncFrom(\sysex, ~sysex);
MIDIIn.removeFuncFrom(\sysrt, ~sysrt);
MIDIIn.removeFuncFrom(\smpte, ~smpte);
)

Quick start for 2 or more ports

example with sound

writing to the bus rather than directly to the synth

//i used this and got acceptable latency for triggering synths live.
//The latency might actually be less than sc2, but i haven't used it enough
//to tell for sure yet.
//Powerbook G4, 512mb ram.
//- matrix6k@somahq.com

s.boot;

(
SynthDef("moto-rev", { |out, ffreq = 100|
    var x;
    x = RLPF.ar(
        LFPulse.ar(
            SinOsc.kr(0.2, 0, 10, 21),
            [0, 0.1],
            0.1
        ),
        ffreq, 0.1
    ).clip2(0.4);
    Out.ar(out, x);
}).add;
)

b = Bus.control(s);

x = Synth("moto-rev");

// map the synth's first input (ffreq) to read
// from the bus' output index
x.map(0, b);

MIDIIn.connect;
//set the action:
(
~noteOn = {arg src, chan, num, vel;
    b.value = num.midicps.postln;
};
MIDIIn.addFuncTo(\noteOn, ~noteOn);

~control = {arg src, chan, num, val;
    [chan,num,val].postln;
};
MIDIIn.addFuncTo(\control, ~control);

~bend = {arg src, chan, val;
    val.postln;
};
MIDIIn.addFuncTo(\bend, ~bend);
)

// cleanup
x.free;
b.free;
MIDIIn.removeFuncFrom(\noteOn, ~noteOn);
MIDIIn.removeFuncFrom(\control, ~control);
MIDIIn.removeFuncFrom(\bend, ~bend);

Keyboard Split for two voices

//pbend to cutoff, mod to rez, 7 to amp
//- matrix6k@somahq.com

s.boot;
(
SynthDef("funk",{ | out, freq = 700, amp = 0.2, gate = 1, cutoff = 20000, rez = 1, lfospeed = 0 |
    var e, x, env, range, filterfreq;
    e = Env.new([0, 0.1, 0.1, 0], [0, 0.1, 0.1], 'linear', 2);
    env = Env.adsr(0.3,1,1,1);
    range = cutoff -1;
    filterfreq = SinOsc.kr(lfospeed,0, range, cutoff).abs;
    x = RLPF.ar(Mix.ar([
            Mix.arFill(2, {Saw.ar(freq *2 + 0.2.rand2, amp)}),
            Mix.arFill(2, {Saw.ar(freq *4+ 0.2.rand2, amp)})
        ]),
        EnvGen.kr(env,gate)*filterfreq,
        rez);
    Out.ar(out, x * EnvGen.kr(e, gate, doneAction: Done.freeSelf))
}).add;

SynthDef("strings", { |out, freq = 700, amp = 0.2, gate = 1|
    var x, enve;
    enve = Env.new([0, 0.1, 0.1, 0], [2, 0.1, 1], 'linear', 2);
    x = RLPF.ar(Mix.ar([
            Mix.arFill(2, {Saw.ar(freq +2.rand2,0.6)}),
            Mix.arFill(2, {Saw.ar(freq *0.5 + 2.rand2,0.6)})
        ]),
        6000,1);
    Out.ar(out, x * EnvGen.kr(enve, gate, doneAction: Done.freeSelf))
}).add;
)

(
var keys, cutspec, cutbus, rezspec, rezbus, lfospec, lfobus;
keys = Array.newClear(128);

MIDIClient.init;
MIDIIn.connect(0, MIDIClient.sources.at(0));

g = Group.new;

cutspec = ControlSpec(100,10000,\linear,0.001);
cutbus = Bus.new(\control,1,1,s);
cutbus.value = 10000;

rezspec = ControlSpec(1,0,\linear,0.001);
rezbus = Bus.new(\control,2,1,s);
rezbus.value = 1.0;

lfospec = ControlSpec(0,50,\linear,0.001);
lfobus = Bus.new(\control,3,1,s);

~control = {arg src, chan, num, val;
    if(num == 1,{
        rezbus.value = rezspec.map(val/127.0);
    });
    if(num == 7,{
        lfobus.value = lfospec.map(val/127.0).postln;
    });
};
MIDIIn.addFuncTo(\control, ~control);

~bend = {arg src, chan, val;
    cutbus.value = cutspec.map(val/16383.0);
};
MIDIIn.addFuncTo(\bend, ~bend);

~noteOn = {arg src, chan, num, vel;
    var node;
    if(num < 60, {
        node = Synth.tail(g, "funk", [\freq, num.midicps, \amp, vel/255]);
        node.map("cutoff",1,"rez",2,"lfospeed",3);
//        node = Synth.basicNew("funk",s);
//        s.sendBundle(nil,
//            node.addToTailMsg(g,[\freq, num.midicps, \amp, vel/255]),
//            node.mapMsg("cutoff",1,"rez",2,"lfospeed",3)
//        );
        keys.put(num, node)
    },{
        node = Synth.tail(g, "strings", [\freq, num.midicps, \amp, vel/255]);
        keys.put(num, node)
    });
};
MIDIIn.addFuncTo(\noteOn, ~noteOn);

~noteOff = {arg src, chan, num, vel;
    var node;
    node = keys.at(num);
    if (node.notNil, {
        keys.put(num, nil);
        s.sendMsg("/n_set", node.nodeID, "gate", 0);
        // or node.release
        // then free it ... or get the NodeWatcher to do it
    });
};
MIDIIn.addFuncTo(\noteOff, ~noteOff);
)

//cleanup
MIDIIn.removeFuncFrom(\noteOn, ~noteOn);
MIDIIn.removeFuncFrom(\control, ~control);
MIDIIn.removeFuncFrom(\bend, ~bend);

helpfile source: /usr/local/share/SuperCollider/HelpSource/Classes/MIDIIn.schelp
link::Classes/MIDIIn::

MIDIIn : Object

MIDIIn.findPort(deviceName, portName)

MIDIIn.addFuncTo(what, func)

Arguments:

MIDIIn.removeFuncFrom(what, func)

Arguments:

MIDIIn.replaceFuncTo(what, func, newFunc)

Arguments:

MIDIIn.noteOnZeroAsNoteOff

MIDIIn.noteOnZeroAsNoteOff = value

MIDIIn.connectAll(verbose: true)

Arguments:

MIDIIn.disconnectAll

MIDIIn.noteOn

MIDIIn.noteOn = value

Arguments:

MIDIIn.noteOff

MIDIIn.noteOff = value

Arguments:

MIDIIn.polytouch

MIDIIn.polytouch = value

Arguments:

MIDIIn.control

MIDIIn.control = value

Arguments:

MIDIIn.program

MIDIIn.program = value

Arguments:

MIDIIn.touch

MIDIIn.touch = value

Arguments:

MIDIIn.bend

MIDIIn.bend = value

Arguments:

MIDIIn.sysex

MIDIIn.sysex = value

Arguments:

MIDIIn.sysrt

MIDIIn.sysrt = value

Arguments:

MIDIIn.smpte

MIDIIn.smpte = value

Arguments:

MIDIIn.action

MIDIIn.action = value

MIDIIn.bendList

MIDIIn.bendList = value

MIDIIn.connect(inport: 0, device: 0)

MIDIIn.controlList

MIDIIn.controlList = value

MIDIIn.disconnect(inport: 0, device: 0)

MIDIIn.doAction(src, status, a, b, c)

MIDIIn.doBendAction(src, chan, val)

MIDIIn.doControlAction(src, chan, num, val)

MIDIIn.doInvalidSysexAction(src, packet)

MIDIIn.doNoteOffAction(src, chan, num, veloc)

MIDIIn.doNoteOnAction(src, chan, num, veloc)

MIDIIn.doPolyTouchAction(src, chan, num, val)

MIDIIn.doProgramAction(src, chan, val)

MIDIIn.doSMPTEaction(src, frameRate, timecode)

MIDIIn.doSysexAction(src, packet)

MIDIIn.doSysrtAction(src, index, val)

MIDIIn.doTouchAction(src, chan, val)

MIDIIn.invalid

MIDIIn.invalid = value

MIDIIn.noteOffList

MIDIIn.noteOffList = value

MIDIIn.noteOnList

MIDIIn.noteOnList = value

MIDIIn.polyList

MIDIIn.polyList = value

MIDIIn.programList

MIDIIn.programList = value

MIDIIn.touchList

MIDIIn.touchList = value

MIDIIn.waitBend(port, chan, val)

MIDIIn.waitControl(port, chan, num, val)

MIDIIn.waitNoteOff(port, chan, note, veloc)

MIDIIn.waitNoteOn(port, chan, note, veloc)

MIDIIn.waitPoly(port, chan, note, veloc)