SuperCollider CLASSES

PV_MagMul

Multiply magnitudes.

Description

Multiplies magnitudes of two inputs and keeps the phases of the first input.

Class Methods

*new (bufferA, bufferB)

Arguments:

bufferA

FFT buffer A.

bufferB

FFT buffer B.

Inherited class methods

Instance Methods

Inherited instance methods

Examples

s.boot;
b = Buffer.read(s, Platform.resourceDir +/+ "sounds/a11wlk01.wav");

(
SynthDef("help-magMul", { arg out=0;
    var inA, chainA, inB, chainB, chain;
    inA = WhiteNoise.ar(0.2);
    inB = LFSaw.ar(100, 0, 0.2);
    chainA = FFT(LocalBuf(2048), inA);
    chainB = FFT(LocalBuf(2048), inB);
    chain = PV_MagMul(chainA, chainB);
    Out.ar(out, 0.1 * IFFT(chain).dup);
}).play(s);
)

(
SynthDef("help-magMul2", { arg out=0, soundBufnum=2;
    var inA, chainA, inB, chainB, chain;
    inA = LFSaw.ar([100, 150], 0, 0.2);
    inB = PlayBuf.ar(1, soundBufnum, BufRateScale.kr(soundBufnum), loop: 1);
    chainA = FFT(LocalBuf(2048), inA);
    chainB = FFT(LocalBuf(2048), inB);
    chain = PV_MagMul(chainA, chainB);
    Out.ar(out,  0.03 * IFFT(chain));
}).play(s, [\soundBufnum, b.bufnum]);
)

b.free