Pdefn | SuperCollider 3.12.2 Help

Description

Pdefn provides an interface to its superclass PatternProxy, keeping a reference to a stream that can be replaced while playing. One pattern may be used in many streams in different places. A change in the pattern definition propagates through all streams.

Pdef and Pdefn use separate global collections.Pdefn(key) //returns the instance Pdefn(key, pat) //defines the pattern and returns the instance, like Pdef, Tdef and Ndef.

It is very similar to PatternProxy.

Pdefn can be used to store value patterns globally (for event patterns, see Pdef). Overview: JITLib

First Example

Class Methods

Pdefn.all

Pdefn.all = value

A global IdentityDictionary with all proxies.

Creation

Pdefn.new(key, item)

Store the pattern in a global dictionary under key, replacing its pattern with the new one. If the pattern is a function, Pdefn creates a Prout with this function, passing in the envir, if given(see below).

Using *new(key) you can access the pattern at that key (if none is given, a default silent event is created)

Arguments:

key

An identifier for the proxy. Usually, it is a Symbol. The key transparently accesses the global IdentityDictionary.

item

An object for (re)defining the source of the proxy. If nil, the proxy is returned unmodified.// pattern as an argument Pdefn(\x, Pseq([1, 2, 5, 6, 7], inf)); Pdefn(\x); // omitting the second argument, we can access the proxy Pdefn(\x).asStream.nextN(20); // ... play one event stream Pdefn(\x).source.postcs; // ... and inspect the event pattern itself. // function as an argument, create a new pattern each time it is called Pdefn(\x, { Pseq({ 10.rand } ! 8) }); Pn(Pdefn(\x)).asStream.nextN(16); // the function is called in the incoming event as current environment, so parameters can be passed: Pdef(\stut, { Pdup(~dup ? 1, ~pattern) }); // we use here a Pdef (not a Pdefn!) Pdefn(\y, Pdef(\stut) <> (pattern: Pdefn(\x), dup: Pseq([2, 2, 4, 3], inf))).asStream.nextN(16);

Pdefn.default

From superclass: PatternProxy

Default source, if none is given. The default is a Pattern that returns 1.0 (This is 1 and not 0 to avoid deadlocks when used as a duration pattern. In a sense, 1 is just as generic as 0).

Pdefn.removeAll

From superclass: PatternProxy

Remove all proxies from the global dictionary ( *all)

Pdefn.clear

From superclass: PatternProxy

Clear all proxies, setting their source to silence.

Pdefn.all

Pdefn.all = value

Set or return the environment ( IdentityDictionary ) that stores all Pdefns.

Inherited class methods

Undocumented class methods

Pdefn.hasGlobalDictionary

Instance Methods

Inherited instance methods

Undocumented instance methods

.copy(toKey)

.dup(n: 2)

.key

.map( ... args)

Examples

Pdefn in expressions

Embedding Pdefn in other patterns

Pdefn(\x, Pseq([1, 2, 3], inf));

x = Pseq([0, 0, Pdefn(\x)], inf).asStream;

t = Task({ loop({ x.next.postln; 0.3.wait }) }).play;

Pdefn(\x, Pseq([55, 66, 77],inf));
Pdefn(\x, Pseq([55, 66, 77],1));

t.stop;

// Pdefn can be accessed in multiple streams

(
SynthDef("Pdefhelp", { arg out, freq, sustain=1, amp=1, pan;
    var env, u=1;
    env = EnvGen.kr(Env.perc(0.03, sustain), 1, doneAction: Done.freeSelf);
    5.do { var d; d = exprand(0.01, 1); u = SinOsc.ar(d * 300, u, rrand(0.1,1.2) * d, 1) };
    Out.ar(out, Pan2.ar(SinOsc.ar(u + 1 * freq, 0, amp * env), pan));

}).add;
s.boot;
)

(
Pdefn(\deg, Pseq([0, 3, 2],inf));

Pset(\instrument, \Pdefhelp,
    Ppar([
        Pbind(\degree, Pdefn(\deg), \pan, -0.8),
        Pbind(\degree, Pdefn(\deg), \dur, 1/3, \pan, 0.8)
])
).play;
)

Pdefn(\deg, Prand([0, 3, [1s, 4]],inf));

Pdefn(\deg, Pn(Pshuf([0, 3, 2, 7, 6],2),inf));

(
Pdefn(\deg, Plazy { var pat;
    pat = [Pshuf([0, 3, 2, 7, 6],2), Pseries(0, 1, 11), Pseries(11, -1, 11)].choose;
    Pn(pat, inf)
});
)

Timing

When does the definition change?

If quant is set, the update is done at the next beat or whatever is specified:Pdefn(\deg).quant = 4; Pdefn(\deg, Pn(Pseries(0, 1, 8),inf)); Pdefn(\deg).quant = nil; // activate immediately again ( Pdefn(\deg, { loop { 5.do { |i| #[1, 3, 4].choose.yield; #[5, 0, 12].choose.yield; #[14, 3, 4].choose.do { |j| (i % j).postln.yield }; } } }) )

update condition

In order to be able to switch to a new pattern under a certain condition, the instance variable condition can be set to a function that returns a boolean. Value and a count index are passed to the function. The condition is always valid for the next pattern inserted. For stuck conditions, the reset message can be used.

As counting up (such as "every nth event, a swap can happen") is a common task, there is a method for this, called count(n).z = Pbind(\degree, Pdefn(\x, \), \dur, 0.25).play; Pdefn(\x, Pseq((0..5), inf)).condition_({ |val, i| i.postln % 6 == 0 }); Pdefn(\x, Pseq((7..0), inf)).condition_({ |val, i| i.postln % 8 == 0 }); // the above is equvalent to: Pdefn(\x, Pseq((7..0), inf)).count(8);

Pdefn : PatternProxy : Pattern : AbstractFunction : Object

Description

First Example

Class Methods

Pdefn.all

Pdefn.all = value

Creation

Pdefn.new(key, item)

Arguments:

Pdefn.default

Pdefn.removeAll

Pdefn.clear

Pdefn.all

Pdefn.all = value

Inherited class methods

Undocumented class methods

Pdefn.hasGlobalDictionary

Instance Methods

Inherited instance methods

Undocumented instance methods

.copy(toKey)

.dup(n: 2)

.key

.map( ... args)

Examples

Pdefn in expressions

Embedding Pdefn in other patterns

Timing

update condition

Reset

Functions as arguments to Pdefn

The (inner) environment