SuperCollider CLASSES

Pmulpre

multiplies with value of a key in event stream, before it is passed up

Description

Multiplies with a value in an event, before it is passed up the stream. To multiply with the value after it has been passed down, use Pmul.

(
var a, b;
a = Pmulpre(\note, 2, Pbind(\note, Pseq([1, 2, 3])));
x = a.asStream;
9.do({ x.next(Event.default).postln; });
)

Pmulpre does not override incoming values:

(
var a, b;
a = Pmulpre(\freq, 801, Pset(\freq, 500, Pbind(\dur, 0.2)));
x = a.asStream;
9.do({ x.next(Event.default).postln; });
)

Class Methods

*new (name, value, pattern)

From superclass: Psetpre

Arguments:

name
value

can be a pattern or a stream. The resulting stream ends when that incoming stream ends.

pattern

Inherited class methods

Instance Methods

Inherited instance methods

Undocumented instance methods

-filterEvent (event, val)

Examples

(
var a, b;
a = Pmulpre(\freq, Pseq([401, 801], 2), Pbind(\dur, 0.5));
x = a.asStream;
9.do({ x.next(Event.new).postln; });
)
//sound example
(
SynthDef(\sinegrain,
    { arg out=0, freq=440, sustain=0.02;
        var env;
        env = EnvGen.kr(Env.perc(0.001, sustain), 1, doneAction:2);
        Out.ar(out, SinOsc.ar(freq, 0, env * 0.1))
    }).add;
)

(
a = Pbind(\dur, 0.5, \instrument, \sinegrain);
b = Pmulpre(\freq, Pseq([1, 2, 3], inf), a);
b.play;
)