SuperCollider CLASSES

Pwhite

random values with uniform distribution
Inherits from: Pattern : AbstractFunction : Object

Class Methods

*new (lo: 0, hi: 1, length: inf)

Arguments:

lo

lower boundary of values.

hi

upper boundary of values.

length

number of values produced.

Inherited class methods

Instance Methods

Inherited instance methods

Undocumented instance methods

-embedInStream (inval)

-hi

-hi = value

-length

-length = value

-lo

-lo = value

Examples

(
var a;
a = Pwhite(0.0, 1.0, inf);
c = a.asStream.nextN(500);
w = Window.new("Pwhite", Rect(10, 10, 540, 800));
// plot the values
c.plot(bounds: Rect(10, 10, 520, 380), discrete: true, parent: w);
// a histogram of the values
c.histo(500).plot(bounds: Rect(10, 410, 520, 380), parent: w);
)

(
var a;
a = Pwhite(0.0, 1.0, inf);
a.asStream.nextN(1000).plot;
)


// sound example
(
SynthDef(\help_sinegrain,
    { arg out=0, freq=440, sustain=0.05;
        var env;
        env = EnvGen.kr(Env.perc(0.01, sustain, 0.2), doneAction:2);
        Out.ar(out, SinOsc.ar(freq, 0, env))
    }).add;
)


(
var a;
a = Pwhite(0.0, 1.0, inf).asStream;
{
    loop {
        Synth(\help_sinegrain, [\freq, a.next * 600 + 300]);
        0.02.wait;
    }
}.fork;
)

// this is equivalent to:
(
{
    loop {
        Synth(\help_sinegrain, [\freq, rrand(0.0, 1.0) * 600 + 300]);
        0.02.wait;
    }
}.fork;
)