Classes | UGens > Generators > Chaotic

QuadC : QuadN : ChaosGen : UGen : AbstractFunction : Object

General quadratic map chaotic generator
Source: Chaos.sc

Description

A cubic-interpolating sound generator based on the difference equation:

    x(n+1) = a * x(n)^2 + b * x(n) + c

sclang code translation:

(
var a = 1, b = -1, c = -0.75, xi = 0, size = 64;
plot(size.collect { xi = (a * (xi ** 2)) + (b * xi) + c; xi });
)

Class Methods

QuadC.ar(freq: 22050, a: 1, b: -1, c: -0.75, xi: 0, mul: 1, add: 0)

From superclass: QuadN

Arguments:

freq

Iteration frequency in Hertz

a

Equation variable

b

Equation variable

c

Equation variable

xi

Initial value of x

Inherited class methods

Instance Methods

Inherited instance methods

Examples

// default params
{ QuadC.ar(SampleRate.ir/4) * 0.2 }.play(s);
// logistic map
// equation: x1 = -r*x0^2 + r*x0
(
{ var r;
    r = MouseX.kr(3.5441, 4);    // stable range
    QuadC.ar(SampleRate.ir/4, r.neg, r, 0, 0.1) * 0.4;
}.play(s);
)
// logistic map as frequency control
(
{ var r;
    r = MouseX.kr(3.5441, 4);    // stable range
    SinOsc.ar(QuadC.ar(40, r.neg, r, 0, 0.1, 800, 900)) * 0.4;
}.play(s);
)