VLayout | SuperCollider 3.14.0-dev Help

Subclasses: QVLayout

Description

See documentation of superclass LineLayout for details.

Examples

// simple example
(
w = Window().front;
a = { Button(w) } ! 10;
w.layout = VLayout(*a);
);

// for a scroll view we need to set its canvas to a View with the desired layout
(
var view = ScrollView();
view.canvas = View().layout_(VLayout(
    *(
        100.collect {
            Slider().orientation_(\horizontal).background_(Color.rand)
        }
    )
));
view.front;
)

// combining HLayout and VLayout

(
w = Window().front;
a = { { Button(w) } ! 10 } ! 10;
w.layout = HLayout(*a.collect { |x| VLayout(*x) });
)

(
w = Window().front;
a = { { PopUpMenu(w, Rect(0, 0, 50, 20)).items_({"abcdefghijklmno".scramble.keep(3)} ! 7) } ! 10 } ! 10;
w.layout = HLayout(*a.collect { |x| VLayout(*x) });
)

(
w = Window().front;
a = { HLayout(Slider(w, Rect(0, 0, 130, 20)), Button(w)) } ! 12;
b = { Slider2D(w) } ! 3;
w.layout = HLayout(VLayout(*a), VLayout(*b));
)

(
w = Window().front;
f = { SoundFileView(w).load(ExampleFiles.child, 1e5.rand, 1e4) };
a = { HLayout(VLayout(*{ Slider(w, Rect(0, 0, 230, 20)).minSize_(Size(130, 20)) } ! 3), f.value) } ! 4;
w.layout = HLayout(VLayout(*a));
)

helpfile source: /usr/local/share/SuperCollider/HelpSource/Classes/VLayout.schelp
link::Classes/VLayout::

VLayout : LineLayout : Layout : QObject : Object

Description

Class Methods

Inherited class methods

Undocumented class methods

VLayout.qtClass

Instance Methods

Inherited instance methods

Examples