«Time and relative dimensions in SC» by 38nonprivate

on 12 Aug'11 11:28 in sound effectsscifi

It's almost the sound of a time travelling device.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
(

{
var output, filtFreq, noise, noiseAmp, amp = 0.4, chain;
var tardRate = 0.4, combs;

noiseAmp = SinOsc.kr(0.38, 0.2).exprange(0.1, 1);

noise = BrownNoise.ar(noiseAmp);

filtFreq = SinOsc.kr(tardRate).range(400, 1800);
noise = RLPF.ar(noise, filtFreq, 0.7);

chain = FFT(LocalBuf(256), noise);
chain = PV_BinShift(chain, SinOsc.kr(tardRate * 0.986, 0.7).range(0.96, 1.052), SinOsc.kr(tardRate * 1.003, 0.61).range(-3, 2.1));
chain = PV_BinScramble(chain, 0.05, 0.1, 1.0 ); 
noise = IFFT(chain);
noise = noise.fold(-0.5, 0.5);
combs = Mix(
 [
 CombL.ar(noise, 0.1, SinOsc.kr(tardRate * 0.9966, 0.1).range(0.00032, 0.00028) * 3.4, 0.4, 0.06),
 CombL.ar(noise, 0.1, SinOsc.kr(tardRate * 0.99684, 0.1).range(0.000318, 0.000266) * 3.397, 0.4, 0.06)
 ]
) * 1.2;

output = (noise + combs) * amp;
output = HPF.ar(output, 80);
output ! 2

}.play

)
descendants
«Re: Time and relative dimensions in SC» by anonymous (private)
full graph
raw 875 chars (focus & ctrl+a+c to copy)
reception
comments
Jascha Narveson user 13 Aug'11 08:02

Tardisian!

all n4tural user 15 Aug'11 15:20

definitely the TARDIS, but it seems to be banging its 'ead against the wall.