BeatTrack2 | SuperCollider 3.12.2 Help

Description

This beat tracker¹ is based on exhaustively testing particular template patterns against feature streams; the testing takes place every 0.5 seconds. The two basic templates are a straight (groove=0) and a swung triplet (groove=1) pattern of 16th notes; this pattern is tried out at scalings corresponding to the tempi from 60 to 180 bpm. This is the cross-correlation method of beat tracking. A majority vote is taken on the best tempo detected, but this must be confirmed by a consistency check after a phase estimate. Such a consistency check helps to avoid wild fluctuating estimates, but is at the expense of an additional half second delay. The latency of the beat tracker with default settings is thus at least 2.5 seconds; because of block-based amortisation of calculation, it is actually around 2.8 seconds latency for a 2.0 second temporal window.

This beat tracker is designed to be flexible for user needs; you can try out different window sizes, tempo weights and combinations of features. However, there are no guarantees on stability and effectiveness, and you will need to explore such parameters for a particular situation.

Class Methods

BeatTrack2.kr(busindex, numfeatures, windowsize: 2.0, phaseaccuracy: 0.02, lock: 0, weightingscheme)

Arguments:

busindex	[sk] Audio input to track, already analysed into N features, passed in via a control bus number from which to retrieve consecutive streams.
numfeatures	[s] How many features (ie how many control buses) are provided
windowsize	[s] Size of the temporal window desired (2.0 to 3.0 seconds models the human temporal window). You might use longer values for stability of estimate at the expense of reactiveness.
phaseaccuracy	[s] Relates to how many different phases to test. At the default, 50 different phases spaced by phaseaccuracy seconds would be tried out for 60bpm; 16 would be tried for 180 bpm. Larger phaseaccuracy means more tests and more CPU cost.
lock	[sk] If this argument is greater than 0.5, the tracker will lock at its current periodicity and continue from the current phase. Whilst it updates the model's phase and period, this is not reflected in the output until lock goes back below 0.5.
weightingscheme	[s] Use (-2.5) for flat weighting of tempi, (-1.5) for compensation weighting based on the number of events tested (because different periods allow different numbers of events within the temporal window) or otherwise a bufnum from 0 upwards for passing an array of 120 individual tempo weights; tempi go from 60 to 179 bpm in steps of one bpm, so you must have a buffer of 120 values.

Returns:

Six k-rate outputs:#beattick, eighthtick, groovetick, tempo, phase, groove = BeatTrack2.kr(busindex, numfeatures)

Inherited class methods

Instance Methods

Inherited instance methods

Examples

// you should load something useful for testing, like a one minute pop song
b = Buffer.read(s, Platform.resourceDir +/+ "sounds/a11wlk01.wav");

//very feature dependent
(
SynthDef(\help_beattrack2_1, { |out, vol=1.0, beepvol=1.0, lock=0, bufnum|
    var in, kbus;
    var trackb, trackh, trackq, tempo, phase, period, groove;
    var bsound, hsound, qsound, beep;
    var fft;
    var feature1, feature2, feature3;

in = PlayBuf.ar(1, bufnum, BufRateScale.kr(bufnum), 1, 0, 1);
    //in = SoundIn.ar(0);

//Create some features
    fft = FFT(LocalBuf(1024), in); //for sampling rates 44100 and 48000
    //fft = FFT(LocalBuf(2048), in); //for sampling rates 88200 and 96000

feature1 = RunningSum.rms(in, 64);
    feature2 = MFCC.kr(fft,2); //two coefficients
    feature3 = A2K.kr(LPF.ar(in,1000));

kbus = Out.kr(0, [feature1, feature3] ++ feature2);

//Look at four features
    #trackb, trackh, trackq, tempo, phase, period, groove = BeatTrack2.kr(0, 4, 2.0, 0.02, lock, -2.5);

beep= SinOsc.ar(1000, 0.0, Decay.kr(trackb, 0.1));
    beep = Pan2.ar((vol * in) + (beepvol * beep), 0.0);
    Out.ar(out, beep);
}).add;
)

a = Synth(\help_beattrack2_1, [\bufnum, b]);
a.set(\vol, 0.0);
a.set(\vol, 1.0);

a.set(\beepvol, 1.0);
a.set(\beepvol, 0.0);

a.set(\lock, 1); //fix it rigidly from current phase/period solution
a.set(\lock, 0); //unfix, back to tracking

a.free;

//same thing, trying with Onsets UGen raw output
(
a= SynthDef(\help_beattrack2_1, { |out, vol=1.0, beepvol=1.0, lock=0, bufnum|
    var in, kbus;
    var trackb, trackh, trackq, tempo, phase, period, groove;
    var bsound, hsound, qsound, beep;
    var fft;
    var feature1, feature2, feature3;

in = PlayBuf.ar(1, bufnum, BufRateScale.kr(bufnum),1,0,1);
    //in = SoundIn.ar(0);

//Create some features
    fft = FFT(LocalBuf(1024), in); // for sampling rates 44100 and 48000
    //fft = FFT(LocalBuf(2048), in); // for sampling rates 88200 and 96000

feature1 = Onsets.kr(fft, odftype:\mkl, rawodf:1);

feature2 = Onsets.kr(fft, odftype:\complex, rawodf:1);//two coefficients

kbus= Out.kr(0, [feature1,feature2]);

//Look at four features
    #trackb, trackh, trackq, tempo, phase, period, groove = BeatTrack2.kr(0, 2, 3.0, 0.02, lock, -2.5);

beep = SinOsc.ar(1000, 0.0, Decay.kr(trackb, 0.1));
    beep = Pan2.ar((vol * in) + (beepvol * beep), 0.0);
    Out.ar(out, beep);
}).add;
)

a = Synth(\help_beattrack2_1, [\bufnum, b]);

[1] - Research note: Designed by Nick Collins following work by Jean Laroche

helpfile source: /usr/local/share/SuperCollider/HelpSource/Classes/BeatTrack2.schelp
link::Classes/BeatTrack2::

BeatTrack2 : MultiOutUGen : UGen : AbstractFunction : Object