Chen | SuperCollider 3.12.2 Help

Description

An implementation of Chen's double scroll chaotic attractor, largely based on Bryan Head's code for the alternative firmware for the Mutable Instruments Stages but heavily modified and tuned to make it as open as possible to SuperCollider users to explore parameter spaces of the algorithm within safe limits and adding interpolation to the parameters to make them modulatable.

This attractor algorithm was proposed by Guanrong Chen in 1999.

Class Methods

Chen.ar(speed: 0.5, a: 0.5, b: 0.3, c: 0.28)

Chen.kr(speed: 0.5, a: 0.5, b: 0.3, c: 0.28)

returns three values: x, y, z (see examples below).

Arguments:

speed	Sets the speed of the chaos generator. This is a normalized value between 0.0 and 1.0. This parameter may be modulated at control rate;
a	A value between 0.0 and 1.0 that sets the a parameter of the algorithm. This is scaled to a nice value in the actual algorithm. This parameter may be modulated at control rate;
b	A value between 0.0 and 1.0 that sets the a parameter of the algorithm. This is scaled to a nice value in the actual algorithm. This parameter may be modulated at control rate;
c	A value between 0.0 and 1.0 that sets the a parameter of the algorithm. This is scaled to a nice value in the actual algorithm. This parameter may be modulated at control rate;

Inherited class methods

Instance Methods

Inherited instance methods

Examples

(
Ndef(\modulated_chen, {|amp=0.5|
    var chenspeedMax = 0.01;
    var chen = Chen.ar(LFCub.kr(0.1).range(0.001,chenspeedMax)); 
    var minfreq = 20.0, maxfreq=2500.0;
    var sig = SinOsc.ar(chen.linexp(0.0,1.0,minfreq,maxfreq));

// Chen returns an array of values sot the ugen above is multi channel expanded
    amp * Splay.ar(sig, spread: chen[0]);
}).play
)

// See it on a scope
(
Ndef(\scoped, {
    var x, y, z;
    #x,y,z = Chen.ar(0.000092);

[x,y,z]
}).scope;
)

(
Ndef(\torn, {|amp=0.5|
    var chenspeedMax = 0.009;
    var chen = Chen.ar(LFCub.kr(LFNoise2.kr(chenspeedMax * 2) * 0.1).range(0.001,chenspeedMax), 0.192, LFCub.kr(0.35).unipolar, 0.22); 
    var minfreq = 40.0, maxfreq=500.0;
    var sig = VarSaw.ar(chen.linexp(0.0,1.0,minfreq,maxfreq), width: chen.reverse.lag);
    sig = sig + FreqShift.ar(sig, chen.scramble.lag3 * 1.0) * 0.5;

// Chen returns an array of values sot the ugen above is multi channel expanded
    amp * Splay.ar(sig, spread: chen.sum / 4.0);
}).play
)

helpfile source: /usr/local/share/SuperCollider/Extensions/MKPlugins/HelpSource/Classes/Chen.schelp
link::Classes/Chen::

Chen : MultiOutUGen : UGen : AbstractFunction : Object Extension