PbindProxy | SuperCollider 3.12.2 Help

Description

keeps a reference to a Pbind in which single keys can be replaced. It plays on when the old stream ended and a new stream is set and schedules the changes to the beat.

Class Methods

PbindProxy.new( ... pairs)

create a new instance of PbindProxy with the given patternpairs

Instance Methods

.set( ... args)

set the given patternpairs.

.at(key)

return a pattern at that key. this can be used to set quant value individually, so different elementary patterns can be quantized differently.x.at(\freq).quant = 2;

.quant = val

set the quant of all elementary patterns, or return the quant value of the source pattern.

.envir = envir

.find(key)

.pairs = value

(
SynthDef("Pdefhelp", { arg out, freq, sustain=1, amp=1, pan;
    var env, u=1;
    env = EnvGen.kr(Env.perc(0.03, sustain), 1, doneAction: Done.freeSelf);
    5.do { var d; d = exprand(0.01, 1); u = SinOsc.ar(d * 300, u, rrand(0.1,1.2) * d, 1) };
    Out.ar(out, Pan2.ar(SinOsc.ar(u + 1 * freq, 0, amp * env), pan));
}).add;
)
s.boot;

x = PbindProxy.new;
x.set(\instrument, \Pdefhelp);

x.play;

x.set(\degree, Pseq([0, 2, 5b, 1b], inf));
x.set(\dur, 0.1);
x.set(\degree, Pseq([1b, 5, 3, 1b, 6, 2, 5, 0, 3, 0, 2], inf));
x.set(\legato, Prand([1.0, 2.4, 0.2], inf), \mtranspose, -3);
x.set(\mtranspose, nil); // remove key

x.set(\degree, Pseq([1, 2, 3, 4, 5, 6], 1));
x.play;

x.set( \degree, Pseq([1, 2, 3, 4, 5, 6], 3), \dur, 0.02);
x.play;

x.set(\degree, Pseq([1, 2, 3, 4, 5, 6], 3), \dur, 0.1);
x.play;

// embed in other patterns:
(
x.set(\degree, Pseq([1b, 5, 3, 1b, 6, 2, 5, 0, 3, 0, 2], inf));
Ppar([
x,
Pbindf(x, \ctranspose, 4)
]).play;
)

x.set(\degree, Pseq([1b, 5, 1b, 4, 0], inf), \dur, 0.4);

helpfile source: /usr/local/share/SuperCollider/HelpSource/Classes/PbindProxy.schelp
link::Classes/PbindProxy::

PbindProxy : Pattern : AbstractFunction : Object

Description

Class Methods

PbindProxy.new( ... pairs)

Inherited class methods

Instance Methods

.source

.set( ... args)

.at(key)

.quant

.quant = val

Inherited instance methods

Undocumented instance methods

.clear

.embedInStream(inval)

.envir

.envir = envir

.find(key)

.pairs

.pairs = value

Examples