SuperCollider CLASSES

EnvirGui

display the contents of an environment for editing
Inherits from: JITGui : Object
Subclasses: NdefParamGui

Description

EnvirGui displays all keys and values of an environment, so one can change them flexibly. Single number get displayed with an EZSlider, pairs of numbers with an EZRanger, and anything else is shown as an EZText (a text field).

Class Methods

Creation

*new (object, numItems: 8, parent, bounds, makeSkip: true, options: [ ])

create a new EnvirGui NdefParamGui

// simple example
g = EnvirGui.new(nil, 5);    // empty with 5 slots
g.parent.alwaysOnTop_(true);
g.object_((a: 1, b: \werty, freq: [500, 2000]));    // put some things in
g.envir.put(\karl1, \otto1);                // one more
g.envir.put(\caesar, \julius);                // one more

g.envir.putAll((b: -12, r: 1, s: 2, t: 3, u: 4, v: 5))

g.object_((x: 2));    // put another object in

g.envir.putAll((b: -12, r: 1, s: 2, t: 3, u: 4, v: 5))

g.envir.removeAt(\b)
g.envir.removeAt(\r)
g.envir.removeAt(\s)
g.envir.removeAt(\t)
g.envir.removeAt(\u)
g.envir.removeAt(\v)
g.close;

Arguments:

object

the envir to display

numItems

the number of items to display. If an envir is given, and no num, num is envir.size.

parent

the parent view to display in; if none is given, a new window is created.

bounds

the bounds within which to display; if none is given, bounds are calculated.

makeSkip

flag whether to make a skipjack to manage updates of the envirgui.

options

configuration options

Inherited class methods

Instance Methods

Instance Variables

-numItems

From superclass: JITGui

how many envir items to display

-envir

-envir = envir

the envir displayed - actually an alias for object.

-zone

From superclass: JITGui

the composite view the envirgui makes for itself

-paramViews

the paramViews that display the values:

See ParamView for details.

-specs

a local dictionary of the specs used for display ranges of numerical parameters by the paramViews of this envirgui. See the -getSpec method for details.

-editKeys

the keys of the currently displayed items in the dict.

-keysRotation

if the size of envir exceeds numItems, the keys displayed can be rotated: e.g. with 10 keys displayed on 5 paramViews, keysRotation 0 means show keys (0..4), keysRotation 2 means show keys (2..6), etc.

gui elements present if requested in options

-docBut

-knowBut

-parentBut

-protoBut

Some Methods

-object

-object = obj

From superclass: JITGui

set the environment to show

Arguments:

obj

can be nil, a dictionary, an environment, or an event.

g = EnvirGui((freq: 120, \amp: 0.2, \pan: -0.5), 12, nil, bounds: Rect(20, 400, 220, 100));
g.object_((a: 1, b: [2, 3], c: \symbol, d: [4, 5, 6], f: { "boing".postln }))

-envir

-envir = envir

same as object_(obj)

-name = name

if in its own window, set the window's name

g.name_("Yoohoo");

-getSpec (key, value)

For editing, numerical parameters need control specs for the ranges on the gui. These can be set locally in the EnvirGui, or global specs will be looked up. If no local or global specs exist for that parameter name, getSpec makes a usable guess for them. (With JITLibExtensions, one can also look up specs attached to an object such as a proxy.)

// inline example
g = EnvirGui.new; g.parent.alwaysOnTop_(true);
g.getSpec(\freq, 400);        // \freq exists as global spec, so use that
g.object_((freq: 150));

g.getSpec(\iFrek, 500);        // no global spec, so make a new one:
                // exponential from val * 0.05 to val * 20;
g.specs;            // and keep it here
g.envir.put(\iFrek, 500);

Arguments:

key

the parameter name for which to find a spec

value

the current value of that param, which is used when guessing specs.

-putSpec (key, obj)

add a spec for a given key, or (if it is a global key) override a global spec with a local one:

// set a desired range and warp:
g.putSpec(\iFrek, [10, 1000, \exp]);
g.putSpec(\freq, [10, 1000, \exp]);
g.specs;
g.putSpec(\freq, \freq);

// specs are remembered when object changes
g.putSpec(\freq, [10, 1000, \exp]);
g.object_((freq: 200, iFrek: 20));

// if needed, clear specs by hand when switching objects
g.specs.clear; g.object_((freq: 200, iFrek: 20));

g.close

-replaceKeys

-addReplaceKey (replaced, replacer, spec)

-removeReplaceKey (replacer)

-showKeyFor (key)

keys with technical names can be replaced in the display with clearer names.

e = (longFreq: 123, amp: 0.25); g = EnvirGui(e); g.parent.alwaysOnTop_(true);

g.editKeys; g.addReplaceKey(\longFreq, \freq1, [50, 500, \exp]); g.viewForParam(\longFreq).visible_(false); g.viewForParam(\freq1).visible_(true);

e.put(\z, 345); e.put(\a, 34);

g.replaceKeys g.removeReplaceKey(\longFreq)

-highlight (index, prefix, color)

-unhighlight (index)

-colorizeArea (area, hilite: true)

methods for visually emphasizing areas.

g.highlight(0, ">>_", Color.red(1, 0.5)); g.unhighlight(0);

Some internal methods

-setByKeys (newKeys)

update the widgets for the current keys

-showFields (num: 0)

show (num) active fields, make others invisible.

-useRanger

-useRanger = value

set and get whether arrays of 2 number values should be displayed with EZRangers.

methods that make gui elements:

-makeViews (options)

-makeNameView (nameWid, height)

-makeOptionalViews (options, height: 20)

-makeKnowBut (width, height)

-makeDocBut (width, height)

-makeClrBut (width, height)

-makeProtoBut (width, height)

-makeParentBut (width, height)

standard JITGui methods:

-accepts (obj)

-setDefaults

-getState

-checkUpdate

-updateButtons

Inherited instance methods

Undocumented instance methods

-setFunc (key)

Examples

    // Setting envir variables in a Tdef:
(
Tdef(\text).set(\note, [0, 2, 7], \dur, { [0.1, 0.2, 0.4].choose }, \pan, 0, \amp, 0.1);

w = Window("EZTexts", Rect(200, 400, 304, 120)).front;
w.addFlowLayout;

TdefGui(Tdef(\text), 0, parent: w);

e = EnvirGui(Tdef(\text).envir, 4, parent: w);

Tdef(\text, { |ev|
    var mydur;
    loop {
        mydur = ev.dur;
        (note: ev.note, dur: mydur, amp: ev.amp, pan: ev.pan).postln.play;
        mydur.wait;
    }
}).play;
)

    // or equivalently, use the built-in EnvirGui in TdefGui:
TdefGui(Tdef(\text), 8);

Tdef(\text).set(\yuhu, Prand([2, 3, 5, 8, 13], inf), \magic, [\abra, \cadabra]);

Tdef(\text).clear;
Tdef(\text).envir.clear;