Dictionary | SuperCollider 3.12.2 Help

Description

A Dictionary is an associative collection mapping keys to values. Two keys match if they are equal. (i.e. == returns true.)

The contents of a Dictionary are unordered. You must not depend on the order of items in a Dictionary. You must only rely on equality for the keys. E.g. symbols and strings can both be used as keys because the matching is done by equality (==) and not by identity (===). For identity matching, where strings can not be used as keys, see: IdentityDictionary and Event.

NOTE: Setting nil as a value erases the key from the Dictionary. This means that nil itself can't be used as a Dictionary value.

Class Methods

Dictionary.new(n: 8)

Creates a Dictionary with an initial capacity for n key value mappings.

Dictionary.newFrom(aCollection)

Creates a new Dictionary from another collection.d= Dictionary.newFrom([\a, 1, \b, 2, \c, 4]);

Arguments:

aCollection

any Object that responds to keysValuesDo (usually a List or an Array).

Discussion:

A new Dictionary can also be created from an array of Associations:Dictionary.with(*[\a->1,\b->2,\c->3])

Or from a single Association like:d = Dictionary[\a -> 1];

Inherited class methods

Instance Methods

Adding and Removing

.add(anAssociation)

Add anAssociation to the Dictionary. If the key value pair already exists in the Dictionary, the key's value will be replaced.( d = Dictionary.new; d.add(\monkey -> 0).postln; d.add(\robot -> 1).postln; // Add robot as a key with a value of 1 d.add(\monkey -> 2).postln; // Replaces the value for the key monkey with 2 )

.put(key, value)

Associate two objects and add them to the Dictionary.d = Dictionary.new; d.put("abc", 10); // using an event: d = (); d.put("abc", 10);

Arguments:

key	key to associate with object. This can be any objects, but is often a Symbol.
value	an object

.removeAt(key)

Remove the key and the value associated with it from the Dictionary.d = Dictionary[\monkey -> 99]; d.removeAt(\monkey);

.putAll( ... dictionaries)

Add all items of each argument to the dictionary.d = Dictionary.new; d.putAll(Dictionary[\hello -> 9, \whello -> "world"], Dictionary["abd" -> 6]);

Arguments:

... dictionaries

any Object that responds to keysValuesDo (usually a Dictionary).

.putPairs(args)

Add all items to the dictionary, using them as key and value pairwise.d = Dictionary.new; d.putPairs([\hello, 10, \whello, "lord", "abc", 7]);

Accessing

.at(key)

Access the value associated with the key.d = Dictionary[\robot -> 99]; d.at(\robot); // Get the value associated with key d[\robot]; // different syntax, same behaviour d.at(\monkey); // Key doesn't exist: return Nil

.atFail(key, function)

Access the value associated with the key. If the key does not exist, return the result of function.

.keys(species)

Return a Set of all keys.d = Dictionary.newFrom([\hello, 9, \whello, "world"]); d.keys;

.values

Return a List of all values.d = Dictionary.newFrom([\hello, 9, \whello, "world"]); d.values;

.atAll(keys)

From superclass: Collection

Return an Array of all values for the given keys.d = Dictionary.newFrom([\hello, 9, \whello, "world", \z, 99, \c, 0.33]); d.atAll([\hello, \z, \hello, \c, \whello]);

.getPairs(args)

Return an Array with all keys and values pairwise.

Discussion:

Note that, unlike -asPairs, getPairs will return nil with an empty Dictionary.d = Dictionary.new; d.getPairs;

.associationAt(key)

Access the Association that has the given key. Element is checked for equality (not identity).d = Dictionary["robot" -> 99]; d.associationAt("robot"); // Get the value associated with key

.findKeyForValue(argValue)

Try to find a given value and return its key. Element is checked for equality (not identity).d = Dictionary.newFrom([\hello, 1, \whello, 77]); d.findKeyForValue(1);

.matchAt(key)

The dictionary's keys are used as conditions against which the arbitrary item is matched. See: matchItemReturns the associated value or nil if no key is matching the item.

NOTE: if an item matches multiple criteria, the value returned is arbitrary. This is because a dictionary is an unordered collection. It's the user's responsibility to make sure that criteria are mutually exclusive.

If the key is an object, the item will be matched by identity (if key === item, the value will be returned).
If the key is a collection, the item is matched if it's contained in the collection.
If the key is a function, the function is evaluated with the item as an argument and the item is matched if the function returns true.

( d = Dictionary.newFrom([ 0, \zero, \abc, \alpha, [1, 2, 3, 5, 8, 13, 21], \fibonacci, { |x| try { x.even } }, \even // try is needed because argument might not be a number ]); ); d.matchAt(0) // matches both 'zero' and 'even', either may be returned d.matchAt(1) d.matchAt(2) // matches both 'fibonacci' and 'even', either may be returned d.matchAt(4) d.matchAt(\abc)

.trueAt(key)

Returns True if the item at the key is true, otherwise false. This method is also valid in Object.

.falseAt(key)

From superclass: Object

Returns False if the item at the key is not true, otherwise true. This method is inherited from Object.

Testing

.includes(item1)

Returns true if the specified item is stored in the Dictionary as a value. Element is checked for equality (not for identity). For identity matching see subclasses: IdentityDictionary or Event.var d = Dictionary.newFrom([\a, "hey", \b, "hello"]); d.includes("hey").postln; // -> true

.includesKey(key)

Returns true if the specified item is stored in the Dictionary as a key. Element is checked for equality (not for identity). For identity matching see subclasses: IdentityDictionary or Event.var d = Dictionary.newFrom(["hey", 1, "hello", 2]); d.includesKey("hey").postln; // -> true

Iteration/Enumeration

Most methods for iteration work analogously to Dictionary's superclasses, see e.g. Collection.

.do(function)

.collect(function)

.reject(function)

.select(function)

.keysValuesDo(function)

Iterate over the associations, and evaluate the function for each, passing key and value as argument.d = Dictionary[\a -> "hello", \b -> "robot", \c -> [1, 2, 3]]; d.keysValuesDo { |key, value| postln("the key: " ++ key ++ " the value: " ++ value) };

.keysValuesChange(function)

Iterate over the associations, and evaluate the function for each, passing key and value as argument. Replace the value with the return value from the function (similar to -collect, but modifies the dictionary in place).d = Dictionary[\a -> "hello", \b -> "robot", \c -> [1, 2, 3]]; d.keysValuesChange { |key, value| "the key: " ++ key ++ " the value: " ++ value }; d;

.keysDo(function)

Iterate over the associations, and evaluate the function for each, passing key as argument.d = Dictionary[\a -> "hello", \b -> "robot", \c -> [1, 2, 3]]; d.keysDo { |key| postln("the key: " ++ key) };

.associationsDo(function)

Iterate over the associations, and evaluate the function for each.d = Dictionary[\a -> "hello", \b -> "robot", \c -> [1, 2, 3]]; d.associationsDo { |assoc| postln("the association: " ++ assoc) };

.pairsDo(function)

Iterate over the associations, and evaluate the function for each, passing key and value as argument. Identical to -keysValuesDo

.invert

Return a new dictionary with all the values as keys and vice versa.d = Dictionary[\a -> "hello", \b -> "robot", \c -> [1, 2, 3]]; d.invert;

Other instance methods

.order(func)

Return an array of keys which corresponds to the order of the values of the dictionary.d = Dictionary[\a -> 5, \b -> 7, \c -> 1, \d -> 0]; d.order; d.atAll(d.order); // returns items in order

.powerset

Return the set of all subsets: here an array of all sub-dictionaries.d = Dictionary[\a -> 5, \b -> 7, \c -> 1, \d -> 0]; d.powerset;

.merge(that, func, fill: true)

Combine two dictionaries into a new one by applying a function to each value. If fill is true (default: true), values missing from one of them are kept as they are.d = Dictionary[\a -> 5, \b -> 7, \d -> 0]; e = Dictionary[\a -> 3, \b -> -3, \c -> 1]; merge(d, e, { |a, b| a + b }); merge(d, e, { |a, b| a + b }, false);

Arguments:

that	another dictionary.
func	a Function.
fill	a Boolean.

.blend(that, blend: 0.5, fill: true, specs)

Blend two dictionaries into a new one by interpolating each value. If fill is true (default: true), values missing from one of them are kept as they are.d = Dictionary[\a -> 5, \b -> 7, \d -> 0]; e = Dictionary[\a -> 3, \b -> -3, \c -> 1]; blend(d, e, 0.3); blend(d, e, 0.3, false); d = Dictionary[\a -> 500, \b -> 0.001]; e = Dictionary[\a -> 300, \b -> 0.1]; blend(d, e, 0.3, specs: (a: \freq, b: \rq));

Arguments:

that	another dictionary.
blend	the blend ratio as a Float between 0.0 and 1.0.
fill	a Boolean.
specs	a dictionary of Specs that are applied to each before blending.

.asSortedArray

Return the values in a sorted array of key value pairs. Sorted by key.d = Dictionary[\a -> 5, \b -> 7, \c -> 1, \d -> 0]; d.asSortedArray;

.asDict(mergeFunc, class)

If no arguments are passed, return itself. This is part of the Key Value Pairs interface.

Arguments:

mergeFunc	This argument is not used, but exists to make the method compatible with Collection: -asDict.
class	A dictionary class to convert to, if given (conversion is done via `newFrom`).

.asPairs(class)

Return the values in an array of alternating key value pairs, like [\freq, 1848, \amp, 0.2]. This is part of the Key Value Pairs interface.

Arguments:

class

The class of the collection to be returned. By default this is an Array.

Discussion:

Note that, unlike -getPairs, asPairs will return an empty Array with an empty Dictionary.d = Dictionary.new; d.asPairs;

.asKeyValuePairs

See -asPairs.

.embedInStream(event)

Arguments:

event

The inval, usually in an event stream. See also Event.

If the event is not nil, yields a copy, adding all the elements of the receiver event (this leaves the receiver unchanged). If it is nil, return the receiver.

Because this pattern is mostly used in the context of events, the following code examples use the shortcut for the subclass Event instead of the Dictionary.a = (note: 2); b = (note: [3, 5]); Pseq([a, b]).play;

If a key "embedInStream" is given, use this function instead. The behaviour of the event can be configured easily this way.

The arguments event (the receiver) and inevent (the inevent) are passed to the function.

NOTE: In infinite patterns, you must call yield or embedInStream in the function, otherwise it will loop forever.

A generator for dictionaries:( d = ( a: 5, b: 7, c: 1, rout: Routine { |inval| inf.do { |i| var event = d.copy.put(\count, i); inval = event.embedInStream(inval); } } ); ) // draw new values d.rout.((z:999)); d.rout.((z:1, a:0)); d.rout.(());

Inherited instance methods

Undocumented instance methods

++(dict)

==(that)

.associationAtFail(argKey, function)

.choose

.fixCollisionsFrom(index)

.grow

.gui( ... args)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/JITLib/GUI/extJITgui.sc

.hash

.isAssociationArray

.keysValuesArrayDo(argArray, function)

.mergeItem(key, val, func)

.printItemsOn(stream, itemsPerLine: 5)

.remove

.removeAtFail(key, function)

.removeFail

.scanFor(argKey)

.softPut(param, val, within: 0.025, mapped: true, lastVal, spec)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/JITLib/GUI/extSoftSet.sc

.softSet(param, val, within: 0.025, mapped: true, lastVal, spec)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/JITLib/GUI/extSoftSet.sc

.sortedKeysValuesDo(function, sortFunc)

.storeItemsOn(stream, itemsPerLine: 5)

.transformEvent(event)

Overview

The Difference between Dictionary, IdentityDictionary, Environment, and Event

Often, the subclass Event is used as an IdentityDictionary, because there is a syntactical shortcut:a = (foo: 7); // return a new Event. a.put(\foo, 2.718); a.at(\foo); a[\foo] = 3.5; // different syntax for put

Event, Environment and IdentityDictionary differ mainly insofar from Dictionary as the keys are taken to be identical (===) objects (see IdentityDictionary), instead of equal (==) objects. By consequence, the subclasses are also faster for indexing. Apart from this, the subclasses add specific functionality only.// preliminary identity and equality of strings and symbols "hello" == "hello"; // true, but "hello" === "hello"; // false. However: \hello === \hello; // true // compare: Dictionary will only store one "hello" Dictionary["hello" -> 0, "hello" -> 1]; // Dictionary[ (hello -> 1) ] // while Event will store both "hello" because they are not identical ("hello": 0, "hello": 1); // ( "hello": 1, "hello": 0 ) // for symbols as keys, Dictionary and Event show the same behaviour: Dictionary[\hello -> 1, \hello -> 0]; // Dictionary[ (hello -> 0) ] ( \hello: 1, \hello: 0 ); // ( 'hello': 0 )

helpfile source: /usr/local/share/SuperCollider/HelpSource/Classes/Dictionary.schelp
link::Classes/Dictionary::

Dictionary : Set : Collection : Object

Dictionary.new(n: 8)

Dictionary.newFrom(aCollection)

Arguments:

Discussion:

.add(anAssociation)

.put(key, value)

Arguments:

.removeAt(key)

.putAll( ... dictionaries)

Arguments:

.putPairs(args)

.at(key)

.atFail(key, function)

.keys(species)

.values

.atAll(keys)

.getPairs(args)

Discussion:

.associationAt(key)

.findKeyForValue(argValue)

.matchAt(key)

.trueAt(key)

.falseAt(key)

.includes(item1)

.includesKey(key)

.do(function)

.collect(function)

.reject(function)

.select(function)

.keysValuesDo(function)

.keysValuesChange(function)

.keysDo(function)

.associationsDo(function)

.pairsDo(function)

.invert

.order(func)

.powerset

.merge(that, func, fill: true)

Arguments:

.blend(that, blend: 0.5, fill: true, specs)

Arguments:

.asSortedArray

.asDict(mergeFunc, class)

Arguments:

.asPairs(class)

Arguments:

Discussion:

.asKeyValuePairs

.embedInStream(event)

Arguments:

++(dict)

==(that)

.associationAtFail(argKey, function)

.choose

.fixCollisionsFrom(index)

.grow

.gui( ... args)

.hash

.isAssociationArray

.keysValuesArrayDo(argArray, function)

.mergeItem(key, val, func)

.printItemsOn(stream, itemsPerLine: 5)

.remove

.removeAtFail(key, function)

.removeFail

.scanFor(argKey)

.softPut(param, val, within: 0.025, mapped: true, lastVal, spec)

.softSet(param, val, within: 0.025, mapped: true, lastVal, spec)

.sortedKeysValuesDo(function, sortFunc)

.storeItemsOn(stream, itemsPerLine: 5)

.transformEvent(event)