SuperCollider CLASSES

String

array of characters

Description

String represents an array of characters.

Strings can be written literally using double quotes:

"my string".class

A sequence of string literals will be concatenated together:

x = "hel" "lo";
y = "this is a\n"
    "multiline\n"
    "string";

A backslash is the escape character. See Literals: Escape%20character.

Class Methods

*readNew (file)

Read the entire contents of a File and return them as a new String.

*scDir

Provided for backwards compatibility.

Returns:

the value of Platform.resourceDir, which is the base resource directory of SuperCollider.

Discussion:

Please use Platform: *resourceDir instead.

Inherited class methods

Instance Methods

Accessing characters

-@ (index)

From superclass: Collection

-at (index)

From superclass: ArrayedCollection

Strings respond to .at in a manner similar to other indexed collections. Each element is a Char.

"ABCDEFG".at(2)

-ascii

Returns an Array of ascii numbers of the Strings's characters.

"wertvoll".ascii

Comparing strings

-compare (aString, ignoreCase: false)

Returns a -1, 0, or 1 depending on whether the receiver should be sorted before the argument, is equal to the argument or should be sorted after the argument. This is a case sensitive compare.

-< (aString)

Returns a Boolean whether the receiver should be sorted before the argument.

"same" < "samf"

-> (aString)

Returns a Boolean whether the receiver should be sorted after the argument.

"same" > "samf"

-<= (aString)

Returns a Boolean whether the receiver should be sorted before the argument, including the same string.

"same" <= "same"
"same" <= "samf"

->= (aString)

Returns a Boolean whether the receiver should be sorted after the argument, including the same string.

"same" >= "same"
"same" >= "samf"

-== (aString)

Returns a Boolean whether the two Strings are equal.

NOTE: This method is (now) case sensitive!

"same" == "same"
"same" == "Same"; // false

-!= (aString)

Returns a Boolean whether the two Strings are not equal.

"same" != "same"; // false
"same" != "Same";

Posting strings

-post

Prints the string to the current post window.

"One".post; "Two".post;"";

-postln

Prints the string and a carriage return to the current post window.

"One".postln; "Two".postln;"";

-postc

-postcln

As -post and -postln, but formatted as a comment.

"This is a comment.".postcln;

-postf ( ... items)

Prints a formatted string with arguments to the current post window. The % character in the format string is replaced by a string representation of an argument. To print a % character use \\% .

postf("this % a %. pi = %, list = %\n", "is", "test", pi.round(1e-4), (1..4))

this is a test. pi = 3.1416, list = [ 1, 2, 3, 4 ]

-postcs

From superclass: Object

As -postln, but posts the compileString of the receiver.

List[1, 2, ["comment", [3, 2]], { 1.0.rand }].postcs;

-error

Prepends an error banner and posts the string.

"Do not press this button again".error;

-warn

Prepends a warning banner and posts the string.

"Do not press this button again".warn;

-inform

Legacy method (although due to widespread use, it will not be removed). This is identical to postln.

Interpreting strings as code

-compile

Compiles a String containing legal SuperCollider code and returns a Function.

(
var f;
f = "2 + 1".compile.postln;
f.value.postln;
)

-interpret

Compile and execute a String containing legal SuperCollider code, returning the result.

"2 + 1".interpret.postln;

-interpretPrint

Compile, execute and print the result of a String containing legal SuperCollider code.

"2 + 1".interpretPrint;

Converting strings

-asCompileString

Returns a String formatted for compiling.

(
var f;
f = "myString";
f.postln;
f.asCompileString.postln;
)

-asSymbol

Return a Symbol derived from the String.

(
var z;
z = "myString".asSymbol.postln;
z.class.postln;
)

-asInteger

Return an Integer derived from the String. Strings beginning with non-numeric characters return 0.

"4".asInteger.postln;

-asFloat

Return a Float derived from the String. Strings beginning with non-numeric characters return 0.

"4.3".asFloat.postln;

-asSecs (maxDays: 365)

Return a Float based on converting a time string in format (dd):hh:mm:ss.s. This is the inverse method to SimpleNumber: -asTimeString.

(45296.asTimeString).asSecs;
"32.1".asSecs;
"62.1".asSecs;        // warns
"0:0:59.9".asSecs;
"1:1:1.1".asSecs;
"-1".asSecs;        // neg sign supported
"-12:34:56".asSecs;
"12:-34:56".asSecs;    // warns
"-23:12.3456".asSecs;    //
"-1:00:00:00".asSecs;    // days too.

Concatenate strings

-++ (anObject)

Return a concatenation of the two strings.

"hello" ++ "word"

-+ (anObject)

Return a concatenation of the two strings with a space between them.

"hello" + "word"

-+/+ (path)

Path concatenation operator - useful for avoiding doubling-up slashes unnecessarily. "foo"+/+"bar" returns "foo/bar"

-catArgs ( ... items)

Concatenate this string with the following args.

"These are some args: ".catArgs(\fish, SinOsc.ar, {4 + 3}).postln;

-scatArgs ( ... items)

Same as -catArgs, but with spaces in between.

"These are some args: ".scatArgs(\fish, SinOsc.ar, {4 + 3}).postln;

-ccatArgs ( ... items)

Same as -catArgs, but with commas in between.

"a String".ccatArgs(\fish, SinOsc.ar, {4 + 3}).postln;

-catList (list)

-scatList (list)

-ccatList (list)

As -catArgs, -scatArgs and -ccatArgs above, but takes a Collection (usually a List or an Array) as an argument.

"a String".ccatList([\fish, SinOsc.ar, {4 + 3}]).postln;

Regular expressions

Note the inversion of the arguments:

findRegexp follows the pattern established by String: -find, where the receiver is the string to be searched. matchRegexp follows the pattern of matchItem, where the receiver is the pattern to match and the first argument is the object to be tested. This is a common source of confusion, but it is based on this precedent.

-matchRegexp (string, start: 0, end)

POSIX regular expression matching. Returns true if the receiver (a regular expression pattern) matches the string passed to it. The start is an offset where to start searching in the string (default: 0), end where to stop.

NOTE: This is regexp.matchRegexp(stringToSearch) and not the other way around! See above: String: Regular%20expressions.
"c".matchRegexp("abcdefg", 2, 5); // true: substring exists
"c".matchRegexp("abcdefg", 4, 5); // false: substring doesn't exist

"behaviou?r".matchRegexp("behavior"); // true: character may or may not exist
"behaviou?r".matchRegexp("behaviour"); // true: character may or may not exist
"behaviou?r".matchRegexp("behavir"); // false: but the rest does not match
"behavi(ou)?r".matchRegexp("behavir"); // true: the substring in parens may or may not exist
"b.h.v.r".matchRegexp("behavor"); // true
"b.h.v.r".matchRegexp("behaviiiiir"); // false: dot stands for exactly one char
"b.h.vi*r".matchRegexp("behaviiiiir"); // true: (kleene) star stands for any number of chars preceding, or none
"b.h.vi*r".matchRegexp("behavuuuur"); // false
"(a|u)nd".matchRegexp("und"); // true
"(a|u)nd".matchRegexp("and"); // true
"[a-c]nd".matchRegexp("ind"); // false
"[a-c]nd".matchRegexp("bnd"); // true: anything between a and c
"[a-c]*nd".matchRegexp("accacaccacand"); //  true: any combination of x, t, z, or none.
"[xtz]+nd".matchRegexp("xnd"); // true: any combination of x, t, z

-findRegexp (regexp, offset: 0)

POSIX regular expression search.

"foobar".findRegexp("o*bar");
"32424 334 /**aaaaaa*/".findRegexp("/\\*\\*a*\\*/");
"foobar".findRegexp("(o*)(bar)");
"aaaabaaa".findAllRegexp("a+");

-findAllRegexp (string, offset: 0)

Like -findAll, but use regular expressions. So unlike findRegexp, it will just return the indices of the

"foobar".findAllRegexp("o*bar");
"32424 334 /**aaaaaa*/".findAllRegexp("/\\*\\*a*\\*/");
"foobar".findAllRegexp("(o*)(bar)");
"aaaabaaa".findAllRegexp("a+");

-findRegexpAt (regexp, offset: 0)

Match a regular expression at the given offset, returning the match and the length of the match in an Array, or nil if it doesn't match. The match must begin right at the offset.

"foobaroob".findRegexpAt("o*b+", 0); // nil
"foobaroob".findRegexpAt("o*b+", 1); // [ oob, 3 ]
"foobaroob".findRegexpAt("o*b+", 2); // [ ob,  2 ]
"foobaroob".findRegexpAt("o*b+", 3); // [ b,   1 ]
"foobaroob".findRegexpAt("o*b+", 4); // nil
"foobaroob".findRegexpAt("o*b+", 5); // nil
"foobaroob".findRegexpAt("o*b+", 6); // [ oob, 3 ]
"foobaroob".findRegexpAt("o*b+", 7); // [ ob,  2 ]

Searching strings

-find (string, ignoreCase: false, offset: 0)

Returns the index of the string in the receiver, or nil if not found. If ignoreCase is true, find makes no difference between uppercase and lowercase letters. The offset is the point in the string where the search begins. string may be a String or a Char.

"These are several words".find("are").postln;
"These are several words".find("fish").postln;

-findBackwards (string, ignoreCase: false, offset: 2147483646)

Same like -find, but starts at the end of the string.

// compare:
"These words are several words".find("words"); // 6
"These words are several words".findBackwards("words"); // 24

-findAll (string, ignoreCase: false, offset: 0)

Returns the indices of the string in the receiver, or nil if not found.

"These are several words which are fish".findAll("are").postln;
"These are several words which are fish".findAll("fish").postln;

-contains (string, offset: 0)

Returns a Boolean indicating if the String contains string.

"These are several words".contains("are").postln;
"These are several words".contains("fish").postln;

-containsi (string, offset: 0)

Same as -contains, but case insensitive.

"These are several words".containsi("ArE").postln;

-containsStringAt (index, string)

Returns a Boolean indicating if the String contains string beginning at the specified index.

"These are several words".containsStringAt(6, "are").postln;

-icontainsStringAt (index, string)

Same as -containsStringAt, but case insensitive.

-beginsWith (string)

-endsWith (string)

Returns true if this string begins/ends with the specified other string.

Arguments:

string

The other string

Returns:

Manipulating strings

-rotate (n: 1)

Rotate the string by n steps.

"hello word".rotate(1)

-scramble

Randomize the order of characters in the string.

"hello word".scramble

-replace (find, replace: "")

Like -tr, but with Strings as well as Chars as arguments.

"Here are several words which are fish".replace("are", "were");

-format ( ... items)

Returns a formatted string with arguments. The % character in the format string is replaced by a string representation of an argument. To print a % character use \\% .

format("this % a %. pi = %, list = %\n", "is", "test", pi.round(1e-4), (1..4))

this is a test. pi = 3.1416, list = [ 1, 2, 3, 4 ]

-escapeChar (charToEscape)

Add the escape character (\) before any character of your choice.

// escape spaces:
"This will become a Unix friendly string".escapeChar($ ).postln;

-quote

Return this string enclosed in double-quote ( " ) characters.

"tell your" + "friends".quote + "not to tread onto the lawn"

-zeroPad

Return this string enclosed in space characters.

"spaces".zeroPad.postcs;

-underlined (char: $-)

Return this string followed by dashes in the next line ( - ).

"underlined".underlined;
"underlined".underlined($~);

-tr (from, to)

Transliteration. Replace all instances of from with to.

":-(:-(:-(".tr($(, $)); //turn the frowns upside down

-padLeft (size, string: " ")

-padRight (size, string: " ")

Pad this string with string so it fills size character.

Arguments:

size

Number of characters to fill

string

Padding string

"this sentence has thirty-nine letters".padRight(39, "-+");
"this sentence has thirty-nine letters".padLeft(39, "-+");
"this sentence more than thirteen letters".padRight(13, "-+"); // nothing to pad.

-toUpper

Return this string with uppercase letters.

"Please, don't be impolite".toUpper;

-toLower

Return this string with lowercase letters.

"SINOSC".toLower;

-stripRTF

Returns a new String with all RTF formatting removed.

(
// same as File-readAllStringRTF
g = File("/code/SuperCollider3/build/Help/UGens/Chaos/HenonC.help.rtf","r");
g.readAllString.stripRTF.postln;
g.close;
)

-split (separator: $/)

Returns an Array of Strings split at the separator. The separator is a Char, and is not included in the output array.

"These are several words".split($ );

// The default separator $/ is handy for Unix paths.
"This/could/be/a/Unix/path".split;

Stream support

-printOn (stream)

Print the String on stream.

"Print this on Post".printOn(Post);

// equivalent to:
Post << "Print this on Post";

-storeOn (stream)

Same as -printOn, but formatted -asCompileString.

"Store this on Post".storeOn(Post);

// equivalent to:
Post <<< "Store this on Post";

Unix Support

Where relevant, the current working directory is the same as the location of the SuperCollider app and the shell is the Bourne shell (sh). Note that the cwd, and indeed the shell itself, does not persist:

"echo $0".unixCmd; // print the shell (sh)
"pwd".unixCmd;
"cd Help/".unixCmd;
"pwd".unixCmd;

"export FISH=mackerel".unixCmd;
"echo $FISH".unixCmd;

It is however possible to execute complex commands:

"pwd; cd Help/; pwd".unixCmd;
"export FISH=mackerel; echo $FISH".unixCmd;

Also on os x applescript can be called via osascript:

"osascript -e 'tell application \"Safari\" to activate'".unixCmd;

Should you need an environment variable to persist you can use -setenv.

NOTE: Despite the fact that the method is called 'unixCmd', it does work in Windows. The string must be a DOS command, however: "dir" rather than "ls" for instance.

-unixCmd (action, postOutput: true)

Execute a UNIX command asynchronously using the standard shell (sh).

Arguments:

action

A Function that is called when the process has exited. It is passed two arguments: the exit code and pid of the exited process.

postOutput

A Boolean that controls whether or not the output of the process is displayed in the post window.

Returns:

An Integer - the pid of the newly created process. Use Integer: -pidRunning to test if a process is alive.

Discussion:

Example:

"ls Help".unixCmd;
"echo one; sleep 1; echo two; sleep 1".unixCmd { |res, pid| [\done, res, pid].postln };

-unixCmdGetStdOut (maxLineLength: 1024)

Similar to -unixCmd except that the stdout of the process is returned (synchronously) rather than sent to the post window.

~listing = "ls Help".unixCmdGetStdOut; // Grab
~listing.reverse.as(Array).stutter.join.postln; // Mangle

-systemCmd

Executes a UNIX command synchronously using the standard shell (sh).

Returns:

Error code of the UNIX command

-runInTerminal (shell: "sh")

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/Collections/linux/extString_linux.sc

Execute the String in a new terminal window (asynchronously).

Arguments:

shell

The shell used to execute the string.

Discussion:

NOTE: On OSX, the string is incorporated into a temporary script file and executed using the shell.

Example:

"echo ---------Hello delightful SuperCollider user----------".runInTerminal;

-setenv (value)

Set the environment variable indicated in the string to equal the String value. This value will persist until it is changed or SC is quit. Note that if value is a path you may need to call -standardizePath on it.

// all defs in this directory will be loaded when a local server boots
"SC_SYNTHDEF_PATH".setenv("~/scwork/".standardizePath);
"echo $SC_SYNTHDEF_PATH".unixCmd;

-getenv

Returns the value contained in the environment variable indicated by the String.

"USER".getenv;

-unsetenv

Set the environment variable to nil.

-mkdir

Make a directory from the given path location.

-pathMatch

Returns an Array containing all paths matching this String. Wildcards apply, non-recursive.

Post << "Help/*".pathMatch;

-load

Load and execute the file at the path represented by the receiver.

-loadPaths (warn: true, action)

Perform -pathMatch on this String, then load and execute all paths in the resultant Array.

//first prepare a file with some code...
(
File.use("/tmp/loadPaths_example.scd", "w", { |file|
    file << "\"This text is the result of a postln command which was loaded and executed by loadPaths\".postln;";
    file <<    "\"I will now throw a dice for you: \".post; 7.rand;"
})
)

// then load the file...
 // ... it posts some text, and the return value pf loadPaths is an array of the return values of each file
"/tmp/loadPaths_example.scd".loadPaths;

Arguments:

warn

Post a warning if path doesn't point to any file.

action

If a function is passed, it is called with each path as argument.

-loadRelative (warn: true, action)

Load and execute the file at the path represented by the receiver, interpreting the path as relative to the current document or text file. Requires that the file has been saved. This can be used e.g. to load initialization code from files in the same folder.

Arguments:

warn

Warn if a file is not found.

action

A function that is called for each file path that is found.

-resolveRelative

Convert the receiver from a relative path to an absolute path, relative to the current document or text file. Requires that the current text file has been saved. Absolute paths are left untransformed.

-standardizePath

Expand ~ to your home directory, and resolve aliases on OSX. See PathName for more complex needs. See File: *realpath if you want to resolve symlinks.

"~/".standardizePath; //This will print your home directory

-openOS

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/Collections/linux/extString_linux.sc

Open file, directory or URL via the operating system. On OSX this is implemented via open, on Linux via xdg-open and on Windows via start.

Platform.userConfigDir.openOS;
"http://supercollider.sf.net".openOS;

Pathname Support

Also see -+/+ for path concatenation.

-shellQuote

Return a new string suitable for use as a filename in a shell command, by enclosing it in single quotes ( ' ). If the string contains any single quotes they will be escaped.

Discussion:

You should use this method on a path before embedding it in a string executed by -unixCmd or -systemCmd.

unixCmd("ls " + Platform.userExtensionDir.shellQuote)

NOTE: This works well with shells such as bash, other shells might need different quotation/escaping. Apart from usage in the construction of shell commands, escaping is not needed for paths passed to methods like pathMatch(path) or File.open(path).

-absolutePath

-asAbsolutePath

Return this path as an absolute path by prefixing it with File: *getcwd if necessary.

-asRelativePath (relativeTo)

Return this path as relative to the specified path.

Arguments:

relativeTo

The path to make this path relative to.

-withTrailingSlash

Return this string with a trailing slash if that was not already the case.

-withoutTrailingSlash

Return this string without a trailing slash if that was not already the case.

-basename

Return the filename from a Unix path.

"Imaginary/Directory/fish.rtf".basename;

-dirname

Return the directory name from a Unix path.

"Imaginary/Directory/fish.rtf".dirname;

-splitext

Split off the extension from a filename or path and return both in an Array as [path or filename, extension].

"fish.rtf".splitext;
"Imaginary/Directory/fish.rtf".splitext;

YAML and JSON parsing

-parseYAML

Parse this string as YAML/JSON.

Returns:

A nested structure of Arrays (for sequences), Dictionaries (for maps) and Strings (for scalars).

-parseYAMLFile

Same as parseYAML but parse a file directly instead of a string. This is faster than reading a file into a string and then parse it.

Document Support

-newTextWindow (title: "Untitled", makeListener: false)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

Create a new Document with this.

"Here is a new Document".newTextWindow;

-openDocument (selectionStart: 0, selectionLength: 0)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

Create a new Document from the path corresponding to this. The selection arguments will preselect the indicated range in the new window. Returns this.

(
String.filenameSymbol.asString.openDocument(10, 20)
)

-findHelpFile

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

Returns the path for the helpfile named this, if it exists, else returns nil.

"Document".findHelpFile;
"foobar".findHelpFile;

-help

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

Performs -findHelpFile on this, and opens the file it if it exists, otherwise opens the main helpfile.

"Document".help;
"foobar".help;

Misc methods

-speak: METHOD NOT FOUND!

Deprecated. See Speech for the full reason and possible replacements. Sends string to the OS X speech synthesizer.

"hi i'm talking with the default voice now, i guess".speak;

-inspectorClass

Returns class StringInspector.

Drawing Support

The following methods must be called within an Window-drawFunc or a SCUserView-drawFunc function, and will only be visible once the window or the view is refreshed. Each call to Window-refresh SCUserView-refresh will 'overwrite' all previous drawing by executing the currently defined function.

See also: Window, UserView, Color, and Pen.

NOTE: for cross-platform GUIs, use Pen.stringAtPoint, Pen.stringInRect, Pen.stringCenteredIn, Pen.stringLeftJustIn, Pen.stringRightJustIn instead.

-draw

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

Draws the String at the current 0@0 Point. If not transformations of the graphics state have taken place this will be the upper left corner of the window. See also Pen.

(
w = Window.new.front;
w.view.background_(Color.white);
w.drawFunc = {
    "abababababa\n\n\n".scramble.draw
};
w.refresh
)

-drawAtPoint (point, font, color)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

Draws the String at the given Point using the Font and Color specified.

(
w = Window.new.front;
w.view.background_(Color.white);
w.drawFunc = {
    "abababababa\n\n\n".scramble.drawAtPoint(
        100@100,
        Font("Courier", 30),
        Color.blue(0.3, 0.5))
};
w.refresh;
)

-drawInRect (rect, font, color)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

Draws the String into the given Rect using the Font and Color specified.

(
w = Window.new.front;
r = Rect(100, 100, 100, 100);
w.view.background_(Color.white);
w.drawFunc = {
    "abababababa\n\n\n".scramble.drawInRect(r, Font("Courier", 12), Color.blue(0.3, 0.5));
    Pen.strokeRect(r);
};
w.refresh;
)

-drawCenteredIn (rect, font, color)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

Draws the String into the given Rect using the Font and Color specified.

(
w = Window.new.front;
w.view.background_(Color.white);
r = Rect(100, 100, 100, 100);
w.drawFunc = {
    "abababababa\n\n\n".scramble.drawCenteredIn(
        r,
        Font("Courier", 12),
        Color.blue(0.3, 0.5)
    );
    Pen.strokeRect(r);
};
w.refresh;
)

-drawLeftJustIn (rect, font, color)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

Draws the String into the given Rect using the Font and Color specified.

(
w = Window.new.front;
w.view.background_(Color.white);
r = Rect(100, 100, 100, 100);
w.drawFunc = {
    "abababababa\n\n\n".scramble.drawLeftJustIn(
        r,
        Font("Courier", 12),
        Color.blue(0.3, 0.5)
    );
    Pen.strokeRect(r);
};
w.refresh;
)

-drawRightJustIn (rect, font, color)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

Draws the String into the given Rect using the Font and Color specified.

(
w = Window.new.front;
w.view.background_(Color.white);
r = Rect(100, 100, 100, 100);
w.drawFunc = {
    "abababababa\n\n\n".scramble.drawRightJustIn(
        r,
        Font("Courier", 12),
        Color.blue(0.3, 0.5)
    );
    Pen.strokeRect(r);
};
w.refresh;
)

-bounds (font)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

Tries to return a Rect with the size needed to fit this string if drawn with given font.

Arguments:

font

A Font

Extensions by SCDoc

-stripWhiteSpace

From extension in /usr/local/share/SuperCollider/SCClassLibrary/SCDoc/SCDoc.sc

Strips whitespace at the beginning and end of the string.

Returns:

The stripped string

-unixCmdGetStdOutLines

From extension in /usr/local/share/SuperCollider/SCClassLibrary/SCDoc/SCDoc.sc

Like -unixCmdGetStdOut but returns the lines in an Array instead.

Returns:

an Array of each line of output

Inherited instance methods

Undocumented instance methods

-asDefName

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/Control/asDefName.sc

-asOSCArgArray

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/Control/extConvertToOSC.sc

-asOSCArgEmbeddedArray (array)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/Control/extConvertToOSC.sc

-asString

-codegen_UGenCtorArg (stream)

-die ( ... culprits)

-exclude

-fformat ( ... args)

-findHelpFileOrElse

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

-gethostbyname

-guiClass

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/tools/guicrucial/gui.sc

-include

-insert (index, string)

-isString

-multiChannelPerform (selector ... args)

-notemidi

From extension in /usr/local/share/SuperCollider/Extensions/SC3plugins/LoopBufUGens/classes/LJP Classes/Extensions/midinote.sc

-openHTMLFile (selectionStart: 0, selectionLength: 0)

From extension in /usr/local/share/SuperCollider/SCClassLibrary/Common/GUI/PlusGUI/Collections/StringPlusGUI.sc

-openHelpFile

From extension in /usr/local/share/SuperCollider/SCClassLibrary/deprecated/3.8/deprecated-3.8.sc

-performBinaryOpOnComplex (aSelector, aComplex)

-performBinaryOpOnSimpleNumber (aSelector, aNumber)

-realPath

-stripHTML

-ugenCodeString (ugenIndex, isDecl, inputNames: [ ], inputStrings: [ ])

-wrapExtend (size)